globals [ 
  total-return-time  ;; used for calc of average return time 
  no-foragers-returned ;; used for calc of average return time
  length-arm         ;; the absolute length of the arms of the t-maze as calculated during setup
  width-arm          ;; the absolute width of the arms of the t-maze as calculated during setup
  half-width-main    ;; half the absolute width of the main branch of the t-maze as calculated during setup
  length-food        ;; the absolute length of food patches of the t-maze as calculated during setup
  half-length-main   ;; half the absolute length of the main branch of the t-maze as calculated during setup
  length-nest        ;; the absoulte length of the nest as calculated during setup
]

patches-own [ 
  chemical           ;; amount of chemicals on patch
  patch-type         ;; 0 = nothing, 1 = nest, 2 = maze, 3 = food-left, 4 = food-right, 5 = left-arm, 6 = right-arm
  nest-scent         ;; scent stronger close to nest
  source-left-scent  ;; scent stronger to left food source, not used at the moment
  source-right-scent ;; scent stronger to right food source, not used at the moment
]

breed [ idle-ants idle-ant ]
breed [ foraging-ants foraging-ant ]
breed [ disappointed-ants disappointed-ant ]
breed [ feeding-ants feeding-ant ]
breed [ returning-ants returning-ant ]
breed [ unloading-ants unloading-ant ]

turtles-own [
  visited-source
  return-time
  moved-this-tick
]

feeding-ants-own [
  load-timer
]

disappointed-ants-own [
  disappointed-timer
]

unloading-ants-own [
  unload-timer
]

to setup
  clear-all
  set-default-shape turtles "bug"
  setup-scale       ;; setup the global scale
  setup-patches     ;; setup t-maze, nest and food sources, including scents
  setup-ants        ;; put population of ants in nest as idle-ants
  do-plotting
end

to setup-scale
  ask patches [
    set length-arm 16 * scale * rel-arm-length
    set width-arm 5 * scale
    set half-width-main 3 * scale
    set length-food 4 * scale
    set half-length-main 12 * scale * rel-main-length
    set length-nest 4 * scale
  ]
end

to setup-patches
  ask patches [
    if pxcor > (length-arm + half-width-main) * (-1) and pxcor <= half-width-main * (-1) and pycor < (half-length-main + width-arm) and pycor > half-length-main [
      set patch-type 5 ; left arm
      set pcolor white
    ]
    if pxcor > half-width-main * (-1) and pxcor <= 0 and pycor < (half-length-main + width-arm) and pycor > half-length-main [
      set patch-type 2 ; left arm to middle
      set pcolor white
    ]
    if pxcor >= 0 and pxcor < half-width-main and pycor < (half-length-main + width-arm) and pycor > half-length-main [
      set patch-type 2 ; right arm to middle
      set pcolor white
    ]
    if pxcor >= half-width-main and pxcor < (half-width-main + length-arm) and pycor < (half-length-main + width-arm) and pycor > half-length-main [
      set patch-type 6 ; right arm
      set pcolor white
    ]
    if pxcor > half-width-main * (-1) and pxcor < half-width-main and pycor <= half-length-main and pycor >= half-length-main * (-1) [
      set patch-type 2 ; main arm
      set pcolor white
    ]
    if pxcor > (length-arm + half-width-main + length-food) * (-1) and pxcor <= (length-arm + half-width-main) * (-1) and pycor < (half-length-main + width-arm) and pycor > half-length-main [
      set patch-type 3 ; left food source
      set pcolor red
    ]
    if pxcor >= (length-arm + half-width-main) and pxcor < (length-arm + half-width-main + length-food) and pycor < (half-length-main + width-arm) and pycor > half-length-main [
      set patch-type 4 ; right food source
      set pcolor red
    ]
    if pxcor > half-width-main * (-1) and pxcor < half-width-main and pycor <= half-length-main * (-1) and pycor > (half-length-main + length-nest) * (-1) [
      set patch-type 1 ; nest
      set pcolor blue
    ]
    let nest-y-center (half-length-main * (-1) - (0.5 * length-nest))
    set nest-scent 100 - distancexy 0 nest-y-center
    set source-left-scent 3200 - distancexy -25 20
    set source-right-scent 3200 - distancexy 25 20
  ]
end

to setup-ants
  create-idle-ants pop-size
  ask idle-ants [
    setxy 0 (half-length-main + length-nest / 2) * (-1)
    set color black
  ]
end


to go
  ask turtles [
    set moved-this-tick false
  ]
  ask idle-ants [
    let exitprob (random 1000 / 1000)
    if exitprob < exit-probability [ set breed foraging-ants ]
    set moved-this-tick true
  ]
  ask feeding-ants with [ moved-this-tick = false ] [
    set color yellow
    ifelse load-timer > 0 [
      set load-timer (load-timer - 1)
    ][
      set breed returning-ants
    ]
    set moved-this-tick true
  ]
  ask disappointed-ants with [ moved-this-tick = false ] [
    set color blue
    move-foraging
    wiggle
    let patch-type-here [patch-type] of patch-here
    if patch-type-here = 1 [
      set breed foraging-ants
    ]
    if ((patch-type-here = 3) and (ticks > delay-left-source)) or ((patch-type-here = 4) and (ticks > delay-right-source))[
      load-forager who
    ]
    set moved-this-tick true
  ]
  ask foraging-ants with [ moved-this-tick = false ] [
    set color black
    move-foraging
    wiggle
    let patch-type-here [patch-type] of patch-here
    if ((patch-type-here = 3) and (ticks > delay-left-source)) or ((patch-type-here = 4) and (ticks > delay-right-source))[
        load-forager who
    ]
    set moved-this-tick true
  ]
  ask returning-ants with [ moved-this-tick = false ] [
    set color yellow
    move-to-nest
    wiggle
    let patch-type-here [patch-type] of patch-here
    if patch-type-here = 1 [
      set breed unloading-ants
      empty-forager who
    ]
    set moved-this-tick true
  ]
  ask unloading-ants with [ moved-this-tick = false ] [
    set color red
    set unload-timer unload-timer - 1
    if unload-timer < 1 [ 
      set breed foraging-ants 
    ]
    set moved-this-tick true
  ]
  ask patches [ 
    set chemical chemical * (100 - evaporation-rate) / 100  ;; slowly evaporate chemical
  ]
  tick
  do-plotting
end

to move-foraging
  ifelse (breed = foraging-ants) and (chemical >= 0.05) [
    uphill-chemical
  ][
    right random 360
  ]
  let move-yes 0
  ask patch-ahead 1 [
    if pcolor = white or pcolor = blue or pcolor = red [ set move-yes 1 ]
  ]
  forward move-yes
end

to load-forager [ forager ]
  ask turtle forager [
    let crowding-levels 0
    set visited-source patch-type
    if patch-type = 3 [ set crowding-levels crowding-levels-left ]
    if patch-type = 4 [ set crowding-levels crowding-levels-right ]
    let number-neighbours count feeding-ants with [load-timer > 0] in-radius 25
    ifelse number-neighbours < crowding-levels [
      set breed feeding-ants
      set load-timer 60
      set visited-source patch-type
      set return-time 0
    ][
      set breed disappointed-ants
      set visited-source patch-type
    ]
  ]
end

to move-to-nest
  uphill-nest-scent
  let ahead-is-path false
  ask patch-ahead 1 [
    if pcolor != black [ set ahead-is-path true ]
  ] 
  ifelse (ahead-is-path = true) [
    set chemical chemical + 60  
    forward 1 
  ][ 
    rt 180 
  ]
  set return-time return-time + 1
end


to empty-forager [ forager ]
  ask unloading-ant forager [ 
    set total-return-time total-return-time + return-time
    set no-foragers-returned no-foragers-returned + 1
    set unload-timer 60
  ]
end

;; sniff left and right, and go where the strongest smell is
to uphill-chemical
  let scent-ahead chemical-scent-at-angle   0
  let scent-right chemical-scent-at-angle  45
  let scent-left  chemical-scent-at-angle -45
  if (scent-right > scent-ahead) or (scent-left > scent-ahead)
  [ ifelse scent-right > scent-left
    [ right 45 ]
    [ left 45 ] ]
end

to-report chemical-scent-at-angle [angle]
  let p patch-right-and-ahead angle 1
  if p = nobody [ report 0 ]
  report [chemical] of p
end

;; sniff left and right, and go where the strongest smell is
to uphill-nest-scent
  let scent-ahead nest-scent-at-angle   0
  let scent-right nest-scent-at-angle  45
  let scent-left  nest-scent-at-angle -45
  if (scent-right > scent-ahead) or (scent-left > scent-ahead)
  [ ifelse scent-right > scent-left
    [ right 45 ]
    [ left 45 ] ]
end

;; wiggle so ants don't get stuck
to wiggle
  right random 40
  left random 40
end

to-report nest-scent-at-angle [angle]
  let result 0
  ask patch-right-and-ahead angle 1 [
    if (pcolor = red) or (pcolor = white) or (pcolor = blue)[
      set result nest-scent
    ]
  ]
  report result
end


;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Plotting procedures ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;

to do-plotting
  set-current-plot "Ants at food source"
  let foragers-left count feeding-ants with [ load-timer > 0 and visited-source = 3 ]
  let foragers-right count feeding-ants with [ load-timer > 0 and visited-source = 4 ]
  set-current-plot-pen "ants-left"
  plotxy ticks foragers-left
  set-current-plot-pen "ants-right"
  plotxy ticks foragers-right
  set-current-plot-pen "ants-with-food"
  plotxy ticks count feeding-ants with [ load-timer > 0 ]
  set-current-plot "Return time"
  set-current-plot-pen "default"
  if no-foragers-returned > 0 [
    plotxy ticks total-return-time / no-foragers-returned
    ;plotxy ticks no-foragers-returned
  ]
  set-current-plot "Pheromone strength"
  let sum-pheromone-left sum [ chemical ] of patches with [ patch-type = 5 ]
  set-current-plot-pen "left"
  plotxy ticks sum-pheromone-left
  let sum-pheromone-right sum [ chemical ] of patches with [ patch-type = 6 ]
  set-current-plot-pen "right"
  plotxy ticks sum-pheromone-right
end
@#$#@#$#@
GRAPHICS-WINDOW
914
19
1614
740
48
48
7.1134021
1
10
1
1
1
0
0
0
1
-48
48
-48
48
0
0
1
seconds

BUTTON
470
19
534
52
Setup
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
472
74
535
107
Go
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
63
57
235
90
evaporation-rate
evaporation-rate
0
10
0.4
0.1
1
NIL
HORIZONTAL

PLOT
66
312
541
603
Ants at food source
ticks
no ants
0.0
10.0
0.0
10.0
true
true
PENS
"ants-left" 1.0 0 -16777216 true
"ants-right" 1.0 0 -13791810 true
"ants-with-food" 1.0 0 -8630108 true

SLIDER
63
16
235
49
pop-size
pop-size
0
500
300
25
1
NIL
HORIZONTAL

PLOT
550
311
894
600
Return time
NIL
NIL
0.0
10.0
0.0
10.0
true
false
PENS
"default" 1.0 0 -16777216 true

SLIDER
268
16
440
49
scale
scale
0.2
1.4
1
0.1
1
NIL
HORIZONTAL

SLIDER
268
56
440
89
rel-arm-length
rel-arm-length
0
1.5
0.65
0.05
1
NIL
HORIZONTAL

SLIDER
65
96
237
129
exit-probability
exit-probability
0
1
1
0.001
1
NIL
HORIZONTAL

SLIDER
64
214
236
247
delay-left-source
delay-left-source
0
3000
3000
50
1
NIL
HORIZONTAL

SLIDER
63
254
235
287
delay-right-source
delay-right-source
0
3000
0
50
1
NIL
HORIZONTAL

SLIDER
65
134
237
167
crowding-levels-left
crowding-levels-left
0
216
25
1
1
NIL
HORIZONTAL

SLIDER
64
174
236
207
crowding-levels-right
crowding-levels-right
0
216
8
1
1
NIL
HORIZONTAL

PLOT
67
610
488
838
Pheromone strength
ticks
sum of pheromones
0.0
10.0
0.0
10.0
true
true
PENS
"left" 1.0 0 -955883 true
"right" 1.0 0 -2064490 true

BUTTON
472
111
554
144
Go once
go
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
269
95
441
128
rel-main-length
rel-main-length
0
1.4
1
.1
1
NIL
HORIZONTAL

@#$#@#$#@
WHAT IS IT?
-----------
Many ants, bees and termites lay pheromone trails to recruit and direct nestmate foragers to food sources. This causes a strong positive feedback as more and more individuals are adding their own pheromones to the trails, as they start exploiting the resource. The feedback will enable a colony of insects to quickly respond to a novel food source, but it can also compormise the flexibility of foraging colony. Experiments have shown that for example ant colonies are sometimes unable to exploit multiple food sources or to quickly switch from a low quality food source to a new one that yields higher quality food. Because of the strong pheromone trails they are locked in a suboptimal state. This model demonstrates that in a stable environment crowding at a food source can can create a negative feedback that is able to break these asymmetries, and can lead to an "ideal free distribution" of foragers. In a changing environment the negative feedback created by crowding enables a colony to quickly re-allocate foragers to newly emerging foodsources.

The model is part of Grüter et al. (in prep): Negative feedback enables fast and flexible collective decision-making in ants. 

PURPOSE
-------
The purpose of the model was to explore the effects of different crowding levels on the allocation of foragers as described in experiments 1 and 2 of Grüter et al. (in prep). Additionally, we tested the role of pheromone decay rates on forager allocation in a changing environment. The model is not intended to be an exact and fully parameterized model of L. niger foraging. While the modelled situation is based on our experimental set-up, the aim was to build a more generic model that captures the key elements of ant foraging and recruitment to investigate how crowding affects worker allocation in a species with strong positive feedback via pheromone trails and negative feedback via crowding at food sources.

ENTITIES, STATE VARIABLES AND SCALES
------------------------------------
For most simulations, we used 500 agents (see table S2 for parameters), which corresponds roughly to the number of ants that can be expected to forage during a typical experimental trial using colonies with several thousand ants (i.e., not all the ants in a colony forage). Agents could assume any one of 6 different states: idle inside the nest, searching for food, feeding at a food patch, at a food patch but unable to feed due to crowding (dissatisfied), laying a pheromone trail while returning to the nest (recruiter), unloading.
 
The simulated agents occupied a specific location at every point in time and were located on a two-dimensional square grid with the shape of a T-maze connected to the nest. The default branch or stem width was 3 squares. The default lengths were 15 squares for the stem and 11 for each arm. The nest was located at the base of the T-maze (3 x 2 squares), with one food patch at the end of each branch (2 x 3 squares). Simulations were run in discrete time steps (t). One time step was made to correspond approximately to one second in the experiment in the following way. It took real ants approximately 40 seconds to walk from a food source to the nest. Hence, for the model we chose branch and stem lengths that required approximately 40 time steps with an agent walking-speed of 1 square per time step (agents did not always walk in a perfectly directly way from nest to feeder). Thus one time step in the model corresponds to one second. Total model running time was 5400 time steps, corresponding to approximately 90 minutes. Because of the stochastic nature of the model, 30 model runs were performed for each combination of parameter values.

PROCESS OVERVIEW AND SCHEDULING
-------------------------------
Agents that left the nest started to perform a random walk (searching) until a food patch or, at a later stage of the simulation, a pheromone trail was encountered. Agents finding a food patch spent 60 time steps taking on food at the patch if there was no crowding. Successful agents then walked directly to the nest and then took 60 time steps to unload. After unloading, agents could leave the nest and start searching again (random walk) or follow a trail. The quality of food patches was high in that all successful agents deposited a pheromone trail with amount C per patch when walking back to the nest. This is a simplification as in nature not all ants deposit trail pheromones and ants also deposit pheromone when walking from the nest to the food source [4]. However, for the purpose of our model this was irrelevant, because we simply wanted the agents to establish an attractive pheromone trail with a certain decay rate. If food patches were crowded, agents became dissatisfied. Dissatisfied agents performed a random walk without paying attention to the pheromone trail or laying a pheromone trail.

During the simulation, the behavioural states and variables were updated for each agent at every time step. The different states were updated asynchronously in sequence (idle agents -> foraging agents -> feeding agents -> dissatisfied agents -> recruiting agents -> unloading agents). However, the model was robust to changes in the sequence. 
In model 1 (corresponding to experiment 1), two identical food sources were offered simultaneously. Fig. 2b shows that 1 feeding hole can accommodate a maximum of 8 foragers. Hence, we again used 4 different crowding levels, which corresponded to the crowding levels in the experiment:  high (8 agents ? 1 feeding hole), medium (24 agents ? 3 feeding holes), low (72 agents ? 9 feeding holes) and very low (216 agents ? 27 feeding holes).  For simplicity, crowding was modelled as an all-or-nothing state. For example, if 8 agents were already present at a food patch in the high crowding situation, other agents at the feeder location could no longer access the food and became dissatisfied. Apart from crowding, food patches were ad libitum as in the experiments.

In model 2 (corresponding to experiment 2), one food source was introduced with a delay of 900 time steps (~ 15 minutes). This second food source permitted 3 times as many agents access to forage before the crowding threshold was reached (8 vs. 24 agents, 24 vs. 72 agents, 72 vs. 216 agents). If the number of agents on a food patch was higher than the crowding threshold for this patch, a newly arrived agent became dissatisfied and performed a random walk.

DESIGN CONCEPTS
---------------
The basic principle addressed by this model is symmetry breaking and how it is affected by negative feedback. To investigate this the This model allows variation in the strength of negative feedback at two food sources to be caused by manipulating the maximum number of agents that can feed at either source. 

The pheromone deposited on the trail system and the proportions of agents at the two food sources, as influenced by both negative and positive feedback, are emergent properties of the model. The concepts of adaptation, objectives and prediction are not important in this model. There is no learning in the model.

Sensing is important in this model: agents leaving the nest were able to detect pheromone left on patches and oriented themselves according to the amount of pheromone. Agents that had fed successfully at either food source, and were walking back to the nest were assumed to know  the direction of the nest (implemented by means of a nest odour). Furthermore, agents reaching the food patch were able to perceive whether the number of agents on a food patch equalled the crowding threshold for this patch (implemented by counting the number of feeding agents on the patch. In nature, ants simply would not be able to access the food source because of the presence of other ants). If so, the agent became dissatisfied and performed a random walk until it was able to feed at the current or at another food source. Hence, the agents interacted in two indirect ways. First, by responding to the pheromone deposited by other agents and, second, by responding to crowding caused by other agents on a food patch.

Stochasticity is used to introduce variability in the number of agents leaving the nest at any time step (Table S2) and in their random walks. 

INITIALISATION
--------------
At the beginning of each simulation trial, the nest, the T-maze and the food sources were initialised as described above. The amount of pheromone chemical was set Cpheromone = 0 for all patches, and the nest scent of patch X was set to Cnest = 100 - distance (Xnest, X), where Xnest is the patch at the centre of the nest. All agents were initiated at the nest centre and their state set to idle, with a probability Pleave (Table S2) to leave the nest. According to the purpose of the model, we tested different initial conditions for crowding levels at food sources, as well as the availability of food at the sources.

INPUT DATA
----------
Apart from changing amounts of pheromone on the different patches of the trail system, the environment is assumed to be constant, so the model has no input data. Food is present as ad libitum throughout. Access to the food is limited but unchanging.

SUBMODELS
---------
The move-foraging submodel defined how agents behave after leaving the nest. If a food patch exceeded a threshold level of pheromone, dissatisfied agents leaving the patch followed pheromone trails by sampling 3 patches in walking direction (0°, 45° left and 45° right) and walking in the direction of the patch with most pheromone. We assumed the pheromone chemical to be volatile, and We used chose a decay evaporation rate that led to a decay of the pheromone trail below the perception threshold of the agents that was equivalent to approximately 45 minutes. This was based on the pheromone strengths we measured during test runs and corresponds to experimentally measured values for L. niger [5]. The amount of pheromone was calculated for each square of the grid at each time step as Ci,t = Ci,(t – 1) × (100 - r)/100; where Ci is the chemical on patch i, r is the evaporation rate in % and t is the time point, leading to an exponential decay (see also table S2). If the current patch had no pheromone or below-threshold pheromone levels, then the agent moved in a random direction.

The move-to-nest submodel defined the behaviour of agents after successful foraging. Full agents perceived the strength of the nest-odour (see section Initialisation) on patches and behaved as they did in the case of pheromone. In nature, ants find their nest relying on various methods such as land-mark learning and path-integration [6,7]. For the purpose of this model, the method of finding the way back to the nest was irrelevant.

SENSITIVITY ANALYSIS
--------------------
In order to test how strongly our results depended on the values of key parameters we systematically varied the number of agents, pheromone decay rates, side branch lengths, and the length of the stem. The model was robust over a wide range of these parameters. Some deviations (e.g. with larger T mazes) are given in the Results section of the main paper.

REFERENCE LIST
--------------

1. Wilensky U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. (Center for Connected Learning and Computer-Based Modeling: Northwestern University, Evanston, IL).
2. Grimm V., Berger U., Bastiansen F., Eliassen S., Ginot V., Giske J., Goss-Custard J., Grand T., Heinz S.K., Huse G. et al. (2006). A standard protocol for describing individual-based and agent-based models. Ecological Modelling 198: 115-126.
3. Grimm V., Berger U., DeAngelis D.L., Polhill J.G., Giske J., and Railsback S.F. (2010). The ODD protocol: A review and first update. Ecological Modelling 221: 2760-2768.
4. Beckers R., Deneubourg J.-L., and Goss S. (1992). Trail laying behaviour during food recruitment in the ant Lasius niger (L.). Insectes Sociaux 39: 59-72.
5. Beckers R., Deneubourg J.-L., and Goss S. (1993). Modulation of trail laying in the ant Lasius niger (Hymenoptera: Formicidae) and its role in the collective selection of a food source. Journal of Insect Behavior 6: 751-759.
6. Collett T.S., Graham P., and Durier V. (2003). Route learning by insects. Current Opinion in Neurobiology 13: 718-725.
7. Collett M. (2009). Spatial memories in insects. Current Biology 19: R1103-R1108.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
0
Rectangle -7500403 true true 151 225 180 285
Rectangle -7500403 true true 47 225 75 285
Rectangle -7500403 true true 15 75 210 225
Circle -7500403 true true 135 75 150
Circle -16777216 true false 165 76 116

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.1.2
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
<experiments>
  <experiment name="1stTrial" repetitions="10" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <timeLimit steps="5400"/>
    <metric>count turtles with [ forager-load-timer &gt; 0 and forager-visited-source = 3 ]</metric>
    <metric>count turtles with [ forager-load-timer &gt; 0 and forager-visited-source = 4 ]</metric>
    <enumeratedValueSet variable="pop-size">
      <value value="400"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="evaporation-rate">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="diffusion-rate">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="crowding-levels-left">
      <value value="8"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="crowding-levels-right">
      <value value="8"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="scale">
      <value value="0.6"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="rel-arm-length">
      <value value="1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="delay-left-source">
      <value value="0"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="delay-right-source">
      <value value="0"/>
    </enumeratedValueSet>
  </experiment>
</experiments>
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 1.0 0.0
0.0 1 1.0 0.0
0.2 0 1.0 0.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@