## fceri_gamma2.bngl
## FceRI receptor activation model
##
## Original rule-based FceRI model was published in:
##   JR Faeder, et al.
##   "Investigation of early events in Fc epsilon RI-mediated signaling
##     using a detailed mathematical model".
##   J. Immunol. 170, 3769–3781 (2003).
##
## "Gamma2" variant appeared in:
##    MW Sneddon, JR Faeder, and T Emonet.
##    "Efficient modeling, simulation and coarse-graining of biological complexity with NFsim".
##    Nature Methods 8, 177–183 (2011).
begin model
begin parameters
    # constants
    NA    6.0221e23  # Avogadro's number
    PI    3.1415927  # Pi

    # experimental conditions (Goldstein, et al. 2004)
    vol_cell      1e-12      # volume of cytoplasm, L

    cell_density  1e9        # cells density, /L
    Rec_cell      4e5        # Receptors per cell: 4e5
    Lyn_cell      3e4        # Lyn molecules per cell: 3e4
    Syk_cell      4e5        # Syk molecules per cell: 4e5
    Lig_conc      10e-9      # initial ligand concentration, M

    # simulation scale
    f         0.001                             # fraction of simulated cell     
    Vec       (1/cell_density)*f                # reactor volume, extracellular
    Vcp       vol_cell*f                        # reactor volume, cytoplasm 

    Lig_tot    Lig_conc*NA*Vec 
    Rec_tot    Rec_cell*f        
    Lyn_tot    Lyn_cell*f
    Syk_tot    Syk_cell*f

    kp1   8e4/NA/Vec        # 8e4 /M/s
    km1   0                 # 0 /s
    kp2   1.51e8/NA/Vcp     # 1.51e8 /M/s (surface reaction. since SA scales with Vcp, this is ok.)
    km2   0                 # 0 /s
    kpL   3.01e7/NA/Vcp     # 3.01e7 /M/s
    kmL   20.               # 20. /s
    kpLs  3.01e7/NA/Vcp     # 3.01e7 /M/s
    kmLs  0.12              # 0.12 /s
    kpS   3.61e7/NA/Vcp     # 3.61e7 /M/s
    kmS   0.13              # /s
    kpSs  6e-2              # /s
    kmSs  0.13              # ...
    pLb   30
    pLbs  100
    pLg   1
    pLgs  3
    pLS   30
    pLSs  100
    pSS   100
    pSSs  200 
    dm    20
    dc    20
end parameters
begin molecule types
    Lig(l,l)
    Lyn(U,SH2)
    Syk(tSH2,l~Y~pY,a~Y~pY)
    Rec(a,b~Y~pY,g~Y~pY,g~Y~pY)
end molecule types
begin species
    Lig(l,l)            Lig_tot 
    Lyn(U,SH2)          Rec_tot
    Syk(tSH2,l~Y,a~Y)   Lyn_tot
    Rec(a,b~Y,g~Y,g~Y)  Syk_tot
end species
begin observables
    Molecules  LynFree    Lyn(U,SH2)
    Molecules  RecMon     Rec(a) Rec(a!1).Lig(l!1,l)
    Molecules  RecDim     Rec(a!0).Lig(l!0,l!1).Rec(a!1)
    Molecules  RecPbeta   Rec(b~pY!?)
    Molecules  RecPgamma  Rec(g~pY!?)
    Molecules  RecSyk     Rec(g~pY!1).Syk(tSH2!1)
    Molecules  RecSykPS   Rec(g~pY!1).Syk(tSH2!1,a~pY)
    Molecules  SykTest    Syk()
    Molecules  LynTest    Lyn()
    Molecules  RecTest    Rec()
    Molecules  LigTest    Lig()
end observables
begin reaction rules
    # Ligand-receptor binding      
    Rec(a) + Lig(l,l) <-> Rec(a!1).Lig(l!1,l)  kp1, km1

    # Receptor-aggregation
    Rec(a) + Lig(l,l!+) <-> Rec(a!1).Lig(l!1,l!+)  kp2,km2

    # Constitutive Lyn-receptor binding
    Rec(b~Y) + Lyn(U,SH2) <-> Rec(b~Y!1).Lyn(U!1,SH2)  kpL, kmL

    # Transphosphorylation of beta by constitutive Lyn
    Lig(l!1,l!2).Lyn(U!3,SH2).Rec(a!2,b~Y!3).Rec(a!1,b~Y) -> Lig(l!1,l!2).Lyn(U!3,SH2).Rec(a!2,b~Y!3).Rec(a!1,b~pY)  pLb

    # Transphosphorylation of gamma by constitutive Lyn
    Lig(l!1,l!2).Lyn(U!3,SH2).Rec(a!2,b~Y!3).Rec(a!1,g~Y) -> Lig(l!1,l!2).Lyn(U!3,SH2).Rec(a!2,b~Y!3).Rec(a!1,g~pY)  pLg

    # Lyn-receptor binding through SH2 domain
    Rec(b~pY) + Lyn(U,SH2) <-> Rec(b~pY!1).Lyn(U,SH2!1)  kpLs, kmLs

    # Transphosphorylation of beta by SH2-bound Lyn
    Lig(l!1,l!2).Lyn(U,SH2!3).Rec(a!2,b~pY!3).Rec(a!1,b~Y) -> Lig(l!1,l!2).Lyn(U,SH2!3).Rec(a!2,b~pY!3).Rec(a!1,b~pY)  pLbs

    # Transphosphorylation of gamma by SH2-bound Lyn
    Lig(l!1,l!2).Lyn(U,SH2!3).Rec(a!2,b~pY!3).Rec(a!1,g~Y) -> Lig(l!1,l!2).Lyn(U,SH2!3).Rec(a!2,b~pY!3).Rec(a!1,g~pY)  pLgs

    # Syk-receptor binding through tSH2 domain
    Rec(g~pY) + Syk(tSH2) <-> Rec(g~pY!1).Syk(tSH2!1)  kpS, kmS

    # Transphosphorylation of Syk by constitutive Lyn
    Lig(l!1,l!2).Lyn(U!3,SH2).Rec(a!2,b~Y!3).Rec(a!1,g~pY!4).Syk(tSH2!4,l~Y) -> \
    Lig(l!1,l!2).Lyn(U!3,SH2).Rec(a!2,b~Y!3).Rec(a!1,g~pY!4).Syk(tSH2!4,l~pY)  pLS

    # Transphosphorylation of Syk by SH2-bound Lyn
    Lig(l!1,l!2).Lyn(U,SH2!3).Rec(a!2,b~pY!3).Rec(a!1,g~pY!4).Syk(tSH2!4,l~Y) -> \
    Lig(l!1,l!2).Lyn(U,SH2!3).Rec(a!2,b~pY!3).Rec(a!1,g~pY!4).Syk(tSH2!4,l~pY)  pLSs

    # Transphosphorylation of Syk by Syk not phosphorylated on aloop
    Lig(l!1,l!2).Syk(tSH2!3,a~Y).Rec(a!2,g~pY!3).Rec(a!1,g~pY!4).Syk(tSH2!4,a~Y) -> \
    Lig(l!1,l!2).Syk(tSH2!3,a~Y).Rec(a!2,g~pY!3).Rec(a!1,g~pY!4).Syk(tSH2!4,a~pY)  pSS

    # Transphosphorylation of Syk by Syk phosphorylated on aloop
    Lig(l!1,l!2).Syk(tSH2!3,a~pY).Rec(a!2,g~pY!3).Rec(a!1,g~pY!4).Syk(tSH2!4,a~Y) -> \
    Lig(l!1,l!2).Syk(tSH2!3,a~pY).Rec(a!2,g~pY!3).Rec(a!1,g~pY!4).Syk(tSH2!4,a~pY)  pSSs

    # Dephosphorylation of Rec beta
    Rec(b~pY)-> Rec(b~Y)  dm

    # Dephosphorylation of Rec gamma
    Rec(g~pY)-> Rec(g~Y)  dm

    # Dephosphorylation of Syk at membrane
    Syk(tSH2!+,l~pY)-> Syk(tSH2!+,l~Y)  dm
    Syk(tSH2!+,a~pY)-> Syk(tSH2!+,a~Y)  dm

    # Dephosphorylation of Syk in cytosol
    Syk(tSH2,l~pY)-> Syk(tSH2,l~Y)  dc
    Syk(tSH2,a~pY)-> Syk(tSH2,a~Y)  dc
end reaction rules
end model